root/OOo/ooo2dbk/trunk/ooo2dbk.odf.xsl

<?xml version="1.0" encoding="UTF-8" ?>
<!DOCTYPE xsl:stylesheet [
<!ENTITY nbsp "&#160;">
]>
<!--
Copyright (c) 2004-2006 Nuxeo SARL <http://nuxeo.com>
Copyright (c) 2003 Stefan Rinke <stefan@stefan-rinke.de>
Copyright (c) 2002 Eric Bellot <ebellot@netcourrier.com>

Authors:
M.-A. Darche (Nuxeo)
Stefan Rinke <stefan@stefan-rinke.de>
Eric Bellot <ebellot@netcourrier.com>
Laurent Godard <lgodard@indesko.com>
Maurice TARDELLI - CERTU/SYS/ITS <Maurice.Tardelli@equipement.gouv.fr> for ODF

This script is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.

This script is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
Lesser General Public License for more details.

You should have received a copy of the GNU Lesser General Public
License along with this library; if not, write to the Free Software
Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA

See ``COPYING`` for more information.

$Id: ooo2dbk.xsl 28486 2005-10-21 13:10:18Z madarche $
-->
<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:office= "urn:oasis:names:tc:opendocument:xmlns:office:1.0" 
    xmlns:style="urn:oasis:names:tc:opendocument:xmlns:style:1.0" 
    xmlns:text="urn:oasis:names:tc:opendocument:xmlns:text:1.0" 
    xmlns:table="urn:oasis:names:tc:opendocument:xmlns:table:1.0" 
    xmlns:draw="urn:oasis:names:tc:opendocument:xmlns:drawing:1.0" 
    xmlns:fo="urn:oasis:names:tc:opendocument:xmlns:xsl-fo-compatible:1.0" 
    xmlns:xlink="http://www.w3.org/1999/xlink" 
    xmlns:dc="http://purl.org/dc/elements/1.1/" 
    xmlns:meta="urn:oasis:names:tc:opendocument:xmlns:meta:1.0" 
    xmlns:number="urn:oasis:names:tc:opendocument:xmlns:datastyle:1.0" 
    xmlns:svg="urn:oasis:names:tc:opendocument:xmlns:svg-compatible:1.0" 
    xmlns:chart="urn:oasis:names:tc:opendocument:xmlns:chart:1.0" 
    xmlns:dr3d="urn:oasis:names:tc:opendocument:xmlns:dr3d:1.0" 
    xmlns:math="http://www.w3.org/1998/Math/MathML" 
    xmlns:form="urn:oasis:names:tc:opendocument:xmlns:form:1.0" 
    xmlns:script="urn:oasis:names:tc:opendocument:xmlns:script:1.0" 
    xmlns:ooo="http://openoffice.org/2004/office" 
    xmlns:ooow="http://openoffice.org/2004/writer" 
    xmlns:oooc="http://openoffice.org/2004/calc" 
    xmlns:dom="http://www.w3.org/2001/xml-events" 
    xmlns:xforms="http://www.w3.org/2002/xforms" 
    xmlns:xsd="http://www.w3.org/2001/XMLSchema" 
    xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
  exclude-result-prefixes="office style text table draw
  fo xlink number svg chart dr3d math form script dc meta ooo ooow oooc dom xforms xsd xsi">

  <xsl:output method="xml" indent="yes" omit-xml-declaration="no"
    doctype-public="-//OASIS//DTD DocBook XML V4.4//EN"
    doctype-system="http://www.oasis-open.org/docbook/xml/4.4/docbookx.dtd"/>
    
  <!--
  Parameter used to determine which top element the resulting tree will have.
  This parameter can be overridden by passing a parameter to the XSLT processor.
  Supported DocBook top elements are: article, book.
  It defaults to "article".
  -->
<xsl:param name="topElementName">book</xsl:param>
<xsl:param name="topElementMetainfoName">
    <xsl:value-of select="concat($topElementName, 'info')"/>
</xsl:param>

<!-- Which unit to use -->
<xsl:param name="measureUnit">
    <xsl:choose>
        <xsl:when test="//table:table">
            <xsl:call-template name="measureUnit"/>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="'unknown'"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:param>
  
<xsl:variable name="oooGenerator" select="/office:document/office:meta/meta:generator"/>
<xsl:variable name="oooVersion">
    <xsl:value-of select="substring-before(substring-after($oooGenerator, 'org/'), ' ')"/>
</xsl:variable>

<xsl:template name="measureUnit">
    <xsl:param name="firstValue" select="//style:page-layout-properties[1]/@fo:page-width"/>
    <xsl:if test="contains(string($firstValue), 'mm')">
      <xsl:value-of select="'mm'"/>
    </xsl:if>
    <xsl:if test="contains(string($firstValue), 'cm')">
      <xsl:value-of select="'cm'"/>
    </xsl:if>
    <xsl:if test="contains(string($firstValue), 'inch')">
      <xsl:value-of select="'inch'"/>
    </xsl:if>
    <xsl:if test="contains(string($firstValue), 'pi')">
      <xsl:value-of select="'pi'"/>
    </xsl:if>
    <xsl:if test="contains(string($firstValue), 'pt')">
      <xsl:value-of select="'pt'"/>
    </xsl:if>
    <xsl:if test="contains(string($firstValue), '%')">
      <xsl:value-of select="'%'"/>
    </xsl:if>
  </xsl:template>

  <!--
  When called with the right parameters this template ouputs a
  processing-instruction specifying the print-orientation for the element that
  has the given style.

  Examples:
  <?print-orientation portrait?>
  <?print-orientation landscape?>

  Details given in the getPrintOrientation template.
  -->
  <xsl:template name="outputPrintOrientation">
    <!-- Mandatory param -->
    <xsl:param name="styleName"/>
    <!-- Optional param -->
    <xsl:param name="parentStyleName" select="''"/>

    <xsl:variable name="printOrientation">
      <xsl:call-template name="getPrintOrientation">
    <xsl:with-param name="styleName" select="$styleName"/>
    <xsl:with-param name="parentStyleName" select="$parentStyleName"/>
      </xsl:call-template>
    </xsl:variable>
    <xsl:if test="string($printOrientation)">
      <xsl:processing-instruction name="print-orientation">
    <xsl:value-of select="$printOrientation"/>
      </xsl:processing-instruction>
    </xsl:if>
  </xsl:template>


  <!--
  Return a string of styles having page orientation information.
  Example of output of this template:
  P1,portrait;P9,portrait;P14,portrait;P19,landscape;P20,landscape;P21,portrait;
  -->
  <xsl:variable name="styleNamesPrintOrientations">
    <xsl:for-each select="/office:document/office:automatic-styles/style:page-layout">
      <xsl:variable name="printOrientation" select="style:page-layout-properties/@style:print-orientation"/>
      <xsl:variable name="pageMasterName" select="@style:name"/>

        <!--<DEBUG><xsl:value-of select="$printOrientation"/></DEBUG>
        <DEBUG><xsl:value-of select="$pageMasterName"/></DEBUG> -->

      <xsl:for-each select="//style:master-page[@style:page-layout-name = $pageMasterName]">
            <xsl:variable name="masterPageName" select="@style:name"/>
            <!--<DEBUG><xsl:value-of select="$masterPageName"/></DEBUG>-->

            <xsl:for-each select="//style:style[@style:master-page-name = $masterPageName]">
                <xsl:value-of select="concat(@style:name, ',')"/>
                <xsl:value-of select="concat($printOrientation, ';')"/>
            </xsl:for-each>
      </xsl:for-each>
    </xsl:for-each>
  </xsl:variable>

  <!--
  When called with the right parameters this template returns the
  print-orientation for the element that has the given style.

  Details:
  The style given to this template should be used the style of a text:h element
  used for defining a part (not in the DocBook or OOo sense) of the OOo
  document. So for example the style could be the one of the title (text:h) of
  the main content or an appendix.

  How it works:
  1. It looks for the page corresponding to the style:master-page-name of the
     given style (contained in the styles.xml file).
  2. It looks for the print-orientation of the page.
  -->
  <xsl:template name="getPrintOrientation">
    <!-- Mandatory param -->
    <xsl:param name="styleName"/>
    <!-- Optional param -->
    <xsl:param name="parentStyleName" select="''"/>
    
    <!-- Implementation finding print-orientation from precomputed list -->
    <xsl:value-of select="substring-before(
      substring-after($styleNamesPrintOrientations, concat($styleName, ',')),
      ';')"/>
    <xsl:if test="string($parentStyleName)">
      <xsl:value-of select="substring-before(
    substring-after($styleNamesPrintOrientations, concat($parentStyleName, ',')),
    ';')"/>
    </xsl:if>

    <!-- Implementation finding print-orientation dynamically -->
    <!--
    <xsl:for-each select="//style:style[@style:name = $styleName]">
      <xsl:variable name="masterPageName" select="@style:master-page-name"/>
      <xsl:for-each select="//style:master-page[@style:name = $masterPageName]">
    <xsl:variable name="pageMasterName" select="@style:page-master-name"/>
    <xsl:for-each select="//style:page-master[@style:name = $pageMasterName]">
      <xsl:value-of select="style:properties/@style:print-orientation"/>
    </xsl:for-each>
      </xsl:for-each>
    </xsl:for-each>
    -->
  </xsl:template>

  <!--
  =============
  DOCUMENT ROOT
  =============
  -->
  <xsl:template match="/">
    <xsl:element name="{$topElementName}">
      <xsl:attribute name="lang">
    <xsl:value-of select="/office:document/office:meta/dc:language"/>
      </xsl:attribute>

      <xsl:processing-instruction name="ooogenerator">
    <xsl:value-of select="$oooGenerator"/>
      </xsl:processing-instruction>
      <xsl:processing-instruction name="oooversion">
    <xsl:value-of select="$oooVersion"/>
      </xsl:processing-instruction>

<!--
    <DEBUG><xsl:value-of select="$measureUnit"/></DEBUG>
    <DEBUG><xsl:value-of select="$styleNamesPrintOrientations"/></DEBUG>
-->
    <xsl:call-template name="metaInfo"/>

      <!--
      Only books can have preface elements.
      A book might have both a Foreword and an Introduction.
      Both should be tagged as preface.
      -->
    <xsl:if test="$topElementName='book'">
        <xsl:call-template name="preface"/>
    </xsl:if>

      <!-- We start with the first title of level 1 -->
      <xsl:choose>
        <xsl:when test="/office:document/office:body/office:text/text:h[@text:outline-level='1']">
            <xsl:apply-templates
            select="/office:document/office:body/office:text/text:h[@text:outline-level='1'][1]"
            mode="hierarchy">
            <xsl:with-param name="source" select="$topElementName"/>
            </xsl:apply-templates>
        </xsl:when>
        <xsl:otherwise>
            <xsl:apply-templates select="/office:document/office:body/office:text"
            mode="noHierarchy"/>
        </xsl:otherwise>
      </xsl:choose>

      <xsl:call-template name="appendix"/>
      <xsl:call-template name="bibliography"/>
      <xsl:call-template name="glossary"/>
      <xsl:call-template name="index"/>
    </xsl:element>
  </xsl:template>


  <!--
  =============================
  CHAPTER AND SECTION HIERARCHY
  =============================
  -->

  <xsl:template match="*|@*" name="hierarchy" mode="hierarchy">
    <!-- Specify which element calls this template (optional) -->
    <xsl:param name="source"/>
    <!-- Store the current depth level (1, 2, etc.) (optional) -->
    <xsl:param name="level" select="'0'"/>
    <!--
    Specify the id of the node you don't want to have in the result set
    (optional)
    -->
    <xsl:param name="excludeNodeId"/>

    <xsl:choose>

      <!-- If the matched element is not a title (text:h) -->
      <xsl:when test="name(.) != 'text:h'">
            <xsl:call-template name="allTags">
              <xsl:with-param name="source" select="'hierarchy'"/>
            </xsl:call-template>
            <xsl:apply-templates select="following-sibling::*[1]" mode="hierarchy">
              <xsl:with-param name="level" select="$level"/>
            </xsl:apply-templates>
      </xsl:when>

      <!-- If the matched element is a title (text:h)
      and is deeper (level) than the preceding title -->
      <xsl:when test="@text:outline-level > $level">

    <!--
    If we want to produce an article it is possible to have paras
    preceding the 1st title at level 1. We want to have those paras too
    when a preface or an appendix is encountered.
    So those instructions are used to display paras that could occur
    before any title is encountered.
    The only case when we don't want to have preceding paras is when the
    source is a book element, the source being the element calling the
    template, which means that a preface in a book can have paras before its
    first title, but chapters in a book cannot have paras before their
    first title.
    -->
    <xsl:if test="$source != 'book'
      and count(preceding-sibling::text:h[@text:outline-level='1']) = 0">
      <xsl:apply-templates select="preceding-sibling::*[
        generate-id(.) != $excludeNodeId]" mode="noHierarchy"/>
    </xsl:if>

    <!--
    We construct a new section (sectn) and the content of the "h" source
    element is placed into the "title" output element.
    -->
        <!-- Debug 
        <level><xsl:value-of select="$level"/></level>
        <source><xsl:value-of select="$source"/></source>-->

    <xsl:if test="$level >= 0">
      <xsl:variable name="structuringElementName">
        <xsl:choose>
          <xsl:when test="$level=0 and $source='book'">
        <xsl:value-of select="'chapter'"/>
          </xsl:when>
          <xsl:otherwise>
        <xsl:value-of select="'section'"/>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:variable>
      <xsl:element name="{$structuringElementName}">

        <!-- rajout MT recherche si bookmark pour les titres et sections
                     si oui on met un id -->
        <xsl:call-template name="GenereIdSection" select="/text:bookmark-start"/>
        <!-- fin rajout MT-->

        <xsl:call-template name="outputPrintOrientation">
          <xsl:with-param name="styleName" select="@text:style-name"/>
        </xsl:call-template>
        <title><xsl:apply-templates/></title>
        <xsl:apply-templates select="following-sibling::*[1]" mode="hierarchy">
          <xsl:with-param name="level" select="@text:outline-level"/>
          <xsl:with-param name="source" select="$source"/>
        </xsl:apply-templates>
      </xsl:element>
    </xsl:if>

    <xsl:apply-templates select="following-sibling::*[1]" mode="scanLevel">
      <xsl:with-param name="level" select="@text:outline-level"/>
      <xsl:with-param name="source" select="$source"/>
    </xsl:apply-templates>

      </xsl:when>

    </xsl:choose>
  </xsl:template>

  <xsl:template match="*" mode="scanLevel">
    <xsl:param name="level" select="'0'"/>
    <xsl:param name="source"/>
    <xsl:choose>
      <xsl:when test="@text:outline-level &lt; $level"/>
      <xsl:when test="@text:outline-level = $level">
    <xsl:call-template name="hierarchy">
      <xsl:with-param name="level" select="$level - 1"/>
      <xsl:with-param name="source" select="$source"/>
    </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
    <xsl:apply-templates select="following-sibling::*[1]" mode="scanLevel">
      <xsl:with-param name="level" select="$level"/>
      <xsl:with-param name="source" select="$source"/>
    </xsl:apply-templates>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

  <xsl:template match="/office:document/office:body/office:text" mode="noHierarchy">
    <xsl:apply-templates mode="noHierarchy"/>
  </xsl:template>

  <xsl:template match="*|@*" mode="noHierarchy">
    <xsl:call-template name="allTags"/>
  </xsl:template>

<xsl:template name="allTags">
    <xsl:param name="source"/>

    <xsl:choose>

        <xsl:when test="name(current())='text:h'">
            <xsl:choose>
                <xsl:when test="$source='hierarchy'"/>
            <xsl:otherwise>
                <para>ERROR: Title hierarchy is wrong, section title is in bad position.</para>
            </xsl:otherwise>
            </xsl:choose>
        </xsl:when>

        <xsl:when test="name(current())='text:p'">
            <xsl:call-template name="para">
                <xsl:with-param name="source" select="$source"/>
            </xsl:call-template>
        </xsl:when>

    <!-- Traitement des liste avec la version 2-->

        <xsl:when test="name(current())='text:list'">
            <xsl:call-template name="ListesV2"/>
        </xsl:when>


        <xsl:when test="name(current())='table:table'">
            <xsl:choose>
                <xsl:when test="$source='cellTable'">
                    <para>ERROR: Section title should not be in a cell.</para>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:call-template name="table"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:when>

    </xsl:choose>
</xsl:template>


  <!--
  ========
  METAINFO
  ========
  -->

  <xsl:template match="/office:document/office:meta"/>
  <xsl:template match="text:p"/>

  <xsl:template name="metaInfo">
    <xsl:param name="bodyRootPara" select="/office:document/office:body/office:text/text:p"/>
    <xsl:element name="{$topElementMetainfoName}">
      <xsl:apply-templates select="$bodyRootPara" mode="metaInfo"/>
      <xsl:apply-templates select="/office:document/office:meta/dc:title"/>
      <xsl:apply-templates select="/office:document/office:meta/dc:date"/>
      <xsl:apply-templates select="/office:document/office:meta/dc:subject"/>
      <xsl:element name="keywordset">
        <xsl:apply-templates select="/office:document/office:meta/meta:keyword"/>
      </xsl:element>
      <xsl:call-template name="abstract"/>
      <xsl:call-template name="userFields"/>
    </xsl:element>
  </xsl:template>


  <xsl:template name="userFields">
    <xsl:call-template name="metainfoUserFields"/>
    <xsl:call-template name="authorUserFields"/>
    <xsl:call-template name="publisherUserFields"/>
    <xsl:call-template name="contractsponsorUserFields"/>
    <xsl:call-template name="conferenceUserFields"/>
  </xsl:template>


  <xsl:template name="metainfoUserFields">
    <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
      text:user-field-decl[@office:string-value!=''
      and starts-with(@text:name, 'metainfo_')]">
      <xsl:if test="@text:name='metainfo_subtitle'">
            <subtitle>
              <xsl:value-of select="@office:string-value"/>
            </subtitle>
      </xsl:if>
      <xsl:if test="@text:name='metainfo_date'">
            <date>
              <xsl:value-of select="@office:string-value"/>
            </date>
      </xsl:if>

      <xsl:if test="@text:name='metainfo_abstract'">
            <abstract>
              <para>
                <xsl:value-of select="@office:string-value"/>
              </para>
            </abstract>
      </xsl:if>

      <xsl:if test="@text:name='metainfo_bibliomisc'">
            <bibliomisc>
              <xsl:value-of select="@office:string-value"/>
            </bibliomisc>
      </xsl:if>

      <xsl:if test="@text:name='metainfo_volumenum'">
            <volumenum>
              <xsl:value-of select="@office:string-value"/>
            </volumenum>
      </xsl:if>

      <xsl:if test="@text:name='metainfo_seriesvolnums'">
            <seriesvolnums>
              <xsl:value-of select="@office:string-value"/>
            </seriesvolnums>
      </xsl:if>

      <xsl:if test="@text:name='metainfo_contractnum'">
            <contractnum>
              <xsl:value-of select="@office:string-value"/>
            </contractnum>
      </xsl:if>

      <xsl:if test="@text:name='metainfo_isbn'">
            <biblioid class="isbn">
              <xsl:value-of select="@office:string-value"/>
            </biblioid>
      </xsl:if>

      <xsl:if test="@text:name='metainfo_issn'">
            <biblioid class="issn">
              <xsl:value-of select="@office:string-value"/>
            </biblioid>
      </xsl:if>

      <xsl:if test="@text:name='metainfo_isrn'">
            <biblioid class="isrn">
              <xsl:value-of select="@office:string-value"/>
            </biblioid>
      </xsl:if>
    </xsl:for-each>
  </xsl:template>

  <xsl:template name="conferenceUserFields">
    <confgroup>
    <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
      text:user-field-decl[@office:string-value!=''
      and starts-with(@text:name, 'metainfo_confgroup')]">
      <xsl:if test="@text:name='metainfo_confgroup_address'">
    <address>
      <xsl:value-of select="@office:string-value"/>
    </address>
      </xsl:if>

      <xsl:if test="@text:name='metainfo_confgroup_confdates'">
    <confdates>
      <xsl:value-of select="@office:string-value"/>
    </confdates>
      </xsl:if>

      <xsl:if test="@text:name='metainfo_confgroup_confnum'">
    <confnum>
      <xsl:value-of select="@office:string-value"/>
    </confnum>
      </xsl:if>

      <xsl:if test="@text:name='metainfo_confgroup_confsponsor'">
    <confsponsor>
      <xsl:value-of select="@office:string-value"/>
    </confsponsor>
      </xsl:if>

      <xsl:if test="@text:name='metainfo_confgroup_conftitle'">
    <conftitle>
      <xsl:value-of select="@office:string-value"/>
    </conftitle>
      </xsl:if>

    </xsl:for-each>
    </confgroup>
  </xsl:template>

  <xsl:template name="authorUserFields">
    <!--
    Testing if there are authors to put in the authorgroup element because
    this element cannot be empty.
    XXX: Maybe there is way to optimize the treatments below where we test if
    there are some nodes (text:user-field-decl) and then look for those same
    nodes over again.
    -->
    <!-- tests if any author metadata exists -->
      <xsl:variable name="hasAuthor">
        <xsl:for-each select="/office:document/office:body/office:user-field-decls/text:user-field-decl[@text:string-value!=''
        and starts-with(@text:name, 'metainfo_author')]">
          <xsl:value-of select="@text:string-value"/>
        </xsl:for-each>
      </xsl:variable>

    <xsl:if test="string($hasAuthor)">
    <authorgroup>
      <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
    text:user-field-decl[@office:string-value!=''
    and starts-with(@text:name, 'metainfo_author')
    and contains(@text:name, '_surname')]">
    <!-- Getting the "namexxx_" string -->
    <xsl:variable name="authorBase"
      select="concat(substring-before(@text:name, '_'), '_',
                     substring-before(substring-after(@text:name, '_'), '_'), '_')"/>
    <author>
      <xsl:variable name="firstname">
        <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
          text:user-field-decl[@text:name=concat($authorBase, 'firstname')]">
          <xsl:value-of select="@office:string-value"/>
        </xsl:for-each>
      </xsl:variable>
      <xsl:if test="string($firstname)">
        <firstname><xsl:value-of select="$firstname"/></firstname>
      </xsl:if>

      <xsl:variable name="surname">
        <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
          text:user-field-decl[@text:name=concat($authorBase, 'surname')]">
          <xsl:value-of select="@office:string-value"/>
        </xsl:for-each>
      </xsl:variable>
      <xsl:if test="string($surname)">
        <surname><xsl:value-of select="$surname"/></surname>
      </xsl:if>

      <xsl:variable name="honorific">
        <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
          text:user-field-decl[@text:name=concat($authorBase, 'honorific')]">
          <xsl:value-of select="@office:string-value"/>
        </xsl:for-each>
      </xsl:variable>
      <xsl:if test="string($honorific)">
        <honorific><xsl:value-of select="$honorific"/></honorific>
      </xsl:if>

        <xsl:variable name="email">
            <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
            text:user-field-decl[@text:name=concat($authorBase, 'email')]">
            <xsl:value-of select="@office:string-value"/>
            </xsl:for-each>
        </xsl:variable>
        <xsl:if test="string($email)">
            <email><xsl:value-of select="$email"/></email>
        </xsl:if>

      <xsl:variable name="orgabbrev">
        <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
          text:user-field-decl[@text:name=concat($authorBase, 'orgname_acronym')]">
          <xsl:value-of select="@office:string-value"/>
        </xsl:for-each>
      </xsl:variable>

      <xsl:variable name="jobtitle">
        <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
          text:user-field-decl[@text:name=concat($authorBase, 'jobtitle')]">
          <xsl:value-of select="@office:string-value"/>
        </xsl:for-each>
      </xsl:variable>

      <xsl:variable name="orgname">
        <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
          text:user-field-decl[@text:name=concat($authorBase, 'orgname')]">
          <xsl:value-of select="@office:string-value"/>
        </xsl:for-each>
      </xsl:variable>
      <xsl:variable name="orgdiv">
        <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
          text:user-field-decl[@text:name=concat($authorBase, 'orgdiv')]">
          <xsl:value-of select="@office:string-value"/>
        </xsl:for-each>
      </xsl:variable>
      <xsl:variable name="address">
        <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
          text:user-field-decl[@text:name=concat($authorBase, 'address')]">
          <xsl:value-of select="@office:string-value"/>
        </xsl:for-each>
      </xsl:variable>
      <xsl:if test="string($jobtitle)
        or string($orgname) or string($orgdiv) or string($orgabbrev) or string($address)">
        <affiliation>
          <xsl:if test="string($orgabbrev)">
        <shortaffil role="orgabbrev"><xsl:value-of select="$orgabbrev"/></shortaffil>
          </xsl:if>
          <xsl:if test="string($jobtitle)">
        <jobtitle><xsl:value-of select="$jobtitle"/></jobtitle>
          </xsl:if>
          <xsl:if test="string($orgname)">
        <orgname><xsl:value-of select="$orgname"/></orgname>
          </xsl:if>
          <xsl:if test="string($orgdiv)">
        <orgdiv><xsl:value-of select="$orgdiv"/></orgdiv>
          </xsl:if>
          <xsl:if test="string($address)">
        <address><xsl:value-of select="$address"/></address>
          </xsl:if>
        </affiliation>
      </xsl:if>
    </author>
      </xsl:for-each>
    </authorgroup>
   </xsl:if>
  </xsl:template>


  <xsl:template name="publisherUserFields">
    <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
      text:user-field-decl[
      @office:string-value != ''
      and starts-with(@text:name, 'metainfo_corpauthor')
      and contains(@text:name, '_orgname')
      and substring-after(@text:name, '_orgname') = ''
      ]">
      <!-- Getting the "corpauthorxxx_" string -->
      <xsl:variable name="authorBase"
      select="concat(substring-before(@text:name, '_'), '_',
                     substring-before(substring-after(@text:name, '_'), '_'), '_')"/>
      <publisher>
    <xsl:variable name="name">
      <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
        text:user-field-decl[@text:name=concat($authorBase, 'orgname')]">
        <xsl:value-of select="@office:string-value"/>
      </xsl:for-each>
    </xsl:variable>
    <xsl:if test="string($name)">
      <publishername><xsl:value-of select="$name"/></publishername>
    </xsl:if>

    <!--
    Unused variable because there is no markup for this information
    in DocBook yet.
    -->
    <xsl:variable name="orgabbrev">
      <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
        text:user-field-decl[@text:name=concat($authorBase, 'orgname_acronym')]">
        <xsl:value-of select="@office:string-value"/>
      </xsl:for-each>
    </xsl:variable>
    <!--
    Unused variable because there is no markup for this information
    in DocBook yet.
    -->
    <xsl:variable name="orgdiv">
      <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
        text:user-field-decl[@text:name=concat($authorBase, 'orgdiv')]">
        <xsl:value-of select="@office:string-value"/>
      </xsl:for-each>
    </xsl:variable>

    <xsl:variable name="street">
      <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
        text:user-field-decl[@text:name=concat($authorBase, 'address')]">
        <xsl:value-of select="@office:string-value"/>
      </xsl:for-each>
    </xsl:variable>
    <xsl:variable name="pob">
      <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
        text:user-field-decl[@text:name=concat($authorBase, 'pob')]">
        <xsl:value-of select="@office:string-value"/>
      </xsl:for-each>
    </xsl:variable>
    <xsl:variable name="postcode">
      <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
        text:user-field-decl[@text:name=concat($authorBase, 'postcode')]">
        <xsl:value-of select="@office:string-value"/>
      </xsl:for-each>
    </xsl:variable>
    <xsl:variable name="city">
      <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
        text:user-field-decl[@text:name=concat($authorBase, 'city')]">
        <xsl:value-of select="@office:string-value"/>
      </xsl:for-each>
    </xsl:variable>
    <xsl:variable name="state">
      <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
        text:user-field-decl[@text:name=concat($authorBase, 'state')]">
        <xsl:value-of select="@office:string-value"/>
      </xsl:for-each>
    </xsl:variable>
    <xsl:variable name="phone">
      <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
        text:user-field-decl[@text:name=concat($authorBase, 'phone')]">
        <xsl:value-of select="@office:string-value"/>
      </xsl:for-each>
    </xsl:variable>
    <xsl:variable name="fax">
      <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
        text:user-field-decl[@text:name=concat($authorBase, 'fax')]">
        <xsl:value-of select="@office:string-value"/>
      </xsl:for-each>
    </xsl:variable>
    <xsl:variable name="email">
      <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
        text:user-field-decl[@text:name=concat($authorBase, 'email')]">
        <xsl:value-of select="@office:string-value"/>
      </xsl:for-each>
    </xsl:variable>
    <xsl:variable name="ulink">
      <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
        text:user-field-decl[@text:name=concat($authorBase, 'ulink')]">
        <xsl:value-of select="@office:string-value"/>
      </xsl:for-each>
    </xsl:variable>

    <xsl:if test="string($street) or string($pob) or string($postcode)
      or string($city) or string($state)
      or string($phone) or string($fax) or string($email) or string($ulink)">
      <address>
        <xsl:if test="string($street)">
          <street><xsl:value-of select="$street"/></street>
        </xsl:if>
        <xsl:if test="string($pob)">
          <pob><xsl:value-of select="$pob"/></pob>
        </xsl:if>
        <xsl:if test="string($postcode)">
          <postcode><xsl:value-of select="$postcode"/></postcode>
        </xsl:if>
        <xsl:if test="string($city)">
          <city><xsl:value-of select="$city"/></city>
        </xsl:if>
        <xsl:if test="string($state)">
          <state><xsl:value-of select="$state"/></state>
        </xsl:if>
        <xsl:if test="string($phone)">
          <phone><xsl:value-of select="$phone"/></phone>
        </xsl:if>
        <xsl:if test="string($fax)">
          <fax><xsl:value-of select="$fax"/></fax>
        </xsl:if>
        <xsl:if test="string($email)">
          <email><xsl:value-of select="$email"/></email>
        </xsl:if>
        <xsl:if test="string($ulink)">
          <otheraddr>
        <ulink>
          <xsl:attribute name="url">
            <xsl:value-of select="$ulink"/>
          </xsl:attribute>
          <xsl:value-of select="$ulink"/>
        </ulink>
          </otheraddr>
        </xsl:if>
      </address>
    </xsl:if>
      </publisher>
    </xsl:for-each>
  </xsl:template>


  <xsl:template name="contractsponsorUserFields">
    <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
      text:user-field-decl[
      @office:string-value!=''
      and starts-with(@text:name, 'metainfo_contractsponsor')
      and contains(@text:name, '_orgname')
      and substring-after(@text:name, '_orgname') = ''
      ]">
      <!-- Getting the "contractsponsorxxx_" string -->
      <xsl:variable name="authorBase"
      select="concat(substring-before(@text:name, '_'), '_',
                     substring-before(substring-after(@text:name, '_'), '_'), '_')"/>
      <xsl:variable name="name">
    <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
      text:user-field-decl[@text:name=concat($authorBase, 'orgname')]">
      <xsl:value-of select="@office:string-value"/>
    </xsl:for-each>
      </xsl:variable>
      <xsl:variable name="street">
        <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
          text:user-field-decl[@text:name=concat($authorBase, 'address')]">
          <xsl:value-of select="@office:string-value"/>
        </xsl:for-each>
      </xsl:variable>
      <xsl:variable name="pob">
        <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
          text:user-field-decl[@text:name=concat($authorBase, 'pob')]">
          <xsl:value-of select="@office:string-value"/>
        </xsl:for-each>
      </xsl:variable>
      <xsl:variable name="postcode">
        <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
          text:user-field-decl[@text:name=concat($authorBase, 'postcode')]">
          <xsl:value-of select="@office:string-value"/>
        </xsl:for-each>
      </xsl:variable>
      <xsl:variable name="city">
        <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
          text:user-field-decl[@text:name=concat($authorBase, 'city')]">
          <xsl:value-of select="@office:string-value"/>
        </xsl:for-each>
      </xsl:variable>
      <xsl:variable name="state">
        <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
          text:user-field-decl[@text:name=concat($authorBase, 'state')]">
          <xsl:value-of select="@office:string-value"/>
        </xsl:for-each>
      </xsl:variable>
      <xsl:variable name="phone">
        <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
          text:user-field-decl[@text:name=concat($authorBase, 'phone')]">
          <xsl:value-of select="@office:string-value"/>
        </xsl:for-each>
      </xsl:variable>
      <xsl:variable name="fax">
        <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
          text:user-field-decl[@text:name=concat($authorBase, 'fax')]">
          <xsl:value-of select="@office:string-value"/>
        </xsl:for-each>
      </xsl:variable>
      <xsl:variable name="email">
        <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
          text:user-field-decl[@text:name=concat($authorBase, 'email')]">
          <xsl:value-of select="@office:string-value"/>
        </xsl:for-each>
      </xsl:variable>
      <xsl:variable name="ulink">
        <xsl:for-each select="/office:document/office:body/office:text/text:user-field-decls/
          text:user-field-decl[@text:name=concat($authorBase, 'ulink')]">
          <xsl:value-of select="@office:string-value"/>
        </xsl:for-each>
      </xsl:variable>

      <contractsponsor>
        <xsl:value-of select="$name"/>
        <xsl:if test="string($street) or string($pob) or string($postcode)
          or string($city) or string($state)
          or string($phone) or string($fax) or string($email) or string($ulink)">
          <xsl:comment>Address</xsl:comment>
        </xsl:if>
        <xsl:if test="string($street)">
          <xsl:processing-instruction name="street">
            <xsl:value-of select="$street"/>
          </xsl:processing-instruction>
        </xsl:if>
        <xsl:if test="string($pob)">
          <xsl:processing-instruction name="pob">
            <xsl:value-of select="$pob"/>
          </xsl:processing-instruction>
        </xsl:if>
        <xsl:if test="string($postcode)">
          <xsl:processing-instruction name="postcode">
            <xsl:value-of select="$postcode"/>
          </xsl:processing-instruction>
        </xsl:if>
        <xsl:if test="string($city)">
          <xsl:processing-instruction name="city">
            <xsl:value-of select="$city"/>
          </xsl:processing-instruction>
        </xsl:if>
        <xsl:if test="string($state)">
          <xsl:processing-instruction name="state">
            <xsl:value-of select="$state"/>
          </xsl:processing-instruction>
        </xsl:if>
        <xsl:if test="string($phone)">
          <xsl:processing-instruction name="phone">
            <xsl:value-of select="$phone"/>
          </xsl:processing-instruction>
        </xsl:if>
        <xsl:if test="string($fax)">
          <xsl:processing-instruction name="fax">
            <xsl:value-of select="$fax"/>
          </xsl:processing-instruction>
        </xsl:if>
        <xsl:if test="string($email)">
          <xsl:processing-instruction name="email">
            <xsl:value-of select="$email"/>
          </xsl:processing-instruction>
        </xsl:if>
        <xsl:if test="string($ulink)">
          <xsl:processing-instruction name="ulink">
            <xsl:value-of select="$ulink"/>
          </xsl:processing-instruction>
        </xsl:if>
      </contractsponsor>
    </xsl:for-each>
  </xsl:template>


  <xsl:template name="keywordsetContent">
    <!--
    keywordsString is a string of coma separated keywords
    Spaces can appear before or after the comas.
    A so called keyword can contain spaces.
    Examples:
    keywordsString = "aaa, bbb, ccc"
    keywordsString = "aaa  ,  bbb  ,ccc"
    keywordsString = "a aa, b bb, ccc"
    keywordsString = "a aa  ,  b bb  ,ccc"
    -->
    <xsl:param name="keywordsString"/>
    <xsl:if test="$keywordsString">
      <xsl:choose>
    <xsl:when test="contains($keywordsString, ',')">
      <keyword><xsl:value-of select="normalize-space(substring-before($keywordsString, ','))"/></keyword>
      <xsl:call-template name="keywordsetContent">
        <xsl:with-param name="keywordsString" select="substring-after($keywordsString, ',')"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <keyword><xsl:value-of select="normalize-space($keywordsString)"/></keyword>
    </xsl:otherwise>
      </xsl:choose>
    </xsl:if>
  </xsl:template>


  <xsl:template name="authorGroupContent">
    <!--
    authorsString is a string of semi-colon separated authors
    Spaces can appear before or after the semi-colons.
    A so called author can contain spaces and a coma.
    If there is a coma for an author, the surname is first and then comes the
    surname. This could have been the other way but this is how it is defined
    in OOo.
    Examples:
    authorsString = "aaa; bbb; ccc"
    authorsString = "aaa  ;  bbb  ;ccc"
    authorsString = "a aa; b bb; ccc"
    authorsString = "a aa  ;  b bb  ;ccc"
    authorsString = " DOE, John  ;  Monroe, Marilyn  ;Buzz"
    -->
    <xsl:param name="authorsString"/>
    <xsl:if test="$authorsString">
      <xsl:choose>
    <xsl:when test="contains($authorsString, ';')">
      <xsl:call-template name="authorGroupContent">
        <xsl:with-param name="authorsString" select="substring-after($authorsString, ';')"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <author>